dataframe/flake.nix at main · DataHaskell/dataframe · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
{
  description = "A fast, safe, and intuitive DataFrame library.";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, flake-utils }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        granitePkg = pkgs.fetchFromGitHub {
          repo = "granite";
          owner = "mchav";
          rev = "main";
          hash = "sha256-Z/o8gxMOBltKiaL0NEjMUyOvUljRvKErWeM6Ul3GM9k=";
        };

        hsPkgs = pkgs.haskellPackages.extend (self: super: {
          granite = self.callCabal2nix "granite" granitePkg { };
          dataframe-fastcsv = self.callCabal2nix "dataframe-fastcsv" ./dataframe-fastcsv { };
          dataframe-persistent = self.callCabal2nix "dataframe-persistent" ./dataframe-persistent { };
          dataframe-hasktorch = self.callCabal2nix "dataframe-hasktorch" ./dataframe-hasktorch { };
          dataframe = self.callCabal2nix "dataframe" ./. { };
        });
      in
      {
        packages = {
          default = hsPkgs.dataframe;
          dataframe = hsPkgs.dataframe;
          dataframe-fastcsv = hsPkgs.dataframe-fastcsv;
          dataframe-hasktorch = hsPkgs.dataframe-hasktorch;
          dataframe-persistent = hsPkgs.dataframe-persistent;
        };

        devShells.default = hsPkgs.shellFor {
          packages = ps: [
            ps.dataframe
            ps.dataframe-fastcsv
            ps.dataframe-persistent
            ps.dataframe-hasktorch
          ];
          nativeBuildInputs = with hsPkgs; [
            ghc
            cabal-install
            haskell-language-server
          ];
          withHoogle = true;
        };
      });
}